Created
August 7, 2017 14:15
-
-
Save jonathanargentiero/7c13a8b633345eeb20f24c0e204363b8 to your computer and use it in GitHub Desktop.
HotKeynet 2 players script
This file contains hidden or bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
| //================================================================ | |
| // SAMPLE SCRIPT FOR TWO WOW'S ON ONE PC | |
| // | |
| // Instructions: Copy this entire script (all the blue writing | |
| // on gray background including comments). Save it in a file. | |
| // Load it into HotkeyNet. | |
| // | |
| // Toggle the scroll lock key to turn hotkeys off and on. (You | |
| // can change this if you want, just like you can change | |
| // everything else with HotkeyNet.) | |
| // | |
| // Requires HotkeyNet build 147 or higher. | |
| // | |
| // For more info, go to www.hotkeynet.com | |
| //================================================================ | |
| //----------------------------------------------------------- | |
| // PRESS CTRL R TO RENAME WOW'S IF YOU LAUNCH THEM MANUALLY | |
| //----------------------------------------------------------- | |
| <Hotkey ScrollLockOn Ctrl R> | |
| <SendPC local> | |
| <RenameWin "World of Warcraft" WoW1> | |
| <RenameWin "World of Warcraft" WoW2> | |
| //----------------------------------------------------------- | |
| // SUBROUTINE TO LAUNCH AND RENAME A COPY OF WOW. | |
| //----------------------------------------------------------- | |
| <Command LaunchAndRename> | |
| <SendPC %1%> | |
| <Run "E:\Games\Wrath of the Lich King 3.3.5a (wod models)\Wow.exe"> | |
| <RenameTargetWin %2%> | |
| //----------------------------------------------------------- | |
| // HOTKEY TO LAUNCH AND RENAME BOTH WOW'S. | |
| //----------------------------------------------------------- | |
| <Hotkey ScrollLockOn Alt Ctrl L> | |
| <LaunchAndRename Local WoW1> | |
| <LaunchAndRename Local WoW2> | |
| //----------------------------------------------------------- | |
| // DEFINE MAIL LABELS FOR SENDING KEY STROKES | |
| //----------------------------------------------------------- | |
| <Label w1 Local SendWinM WoW1> | |
| <Label w2 Local SendWinM WoW2> | |
| //----------------------------------------------------------- | |
| // DEFINE HOTKEYS FOR ALL KEY COMBINATIONS THAT WILL GET | |
| // SENT TO BOTH WOWS. ADD MORE KEY COMBO'S IF YOU WANT. | |
| //----------------------------------------------------------- | |
| <Hotkey ScrollLockOn A-Z, 0-9, Plus, Minus, Numpad1, Numpad2, Numpad3, Numpad4, Numpad5, Numpad6, Numpad7, Numpad8, Numpad9, Numpad0, NumpadPlus, NumpadMinus, F1-F12 except W, A, S, D, Q, E> | |
| <SendLabel w1, w2> | |
| <Key %Trigger%> | |
| //----------------------------------------------------------- | |
| // DEFINE MOVEMENT KEYS THAT WILL GET SENT TO BOTH WOW'S. | |
| // ADD MORE KEYS IF YOU WANT. | |
| //----------------------------------------------------------- | |
| <MovementHotkey ScrollLockOn up, down, left, right> | |
| <SendLabel w1, w2> | |
| <Key %Trigger%> | |
| //----------------------------------------------------------- | |
| // BROADCAST MOUSE CLICKS. HOLD DOWN OEM3 (ON U.S. KEYBOARDS, | |
| // THAT'S THE SQUIGGLE KEY IN UPPPER LEFT CORNER) WHEN YOU | |
| // WANT TO BROADCAST. | |
| //----------------------------------------------------------- | |
| <UseKeyAsModifier Oem3> | |
| <Hotkey ScrollLockOn Oem3 LButton, MButton, RButton, Button4, Button5> | |
| <SendLabel w1, w2> | |
| <ClickMouse %TriggerMainKey%> |
Sign up for free
to join this conversation on GitHub.
Already have an account?
Sign in to comment