klinovp/rdf-list-from-data.md

Last active October 7, 2021 07:34

Star (0) You must be signed in to star a gist
Fork (0) You must be signed in to fork a gist

Select an option

Learn more about clone URLs
Clone this repository at <script src="https://gist.github.com/klinovp/e4c4594143ed91e10c44226535eae698.js"></script>
Save klinovp/e4c4594143ed91e10c44226535eae698 to your computer and use it in GitHub Desktop.

Download ZIP

Generate an RDF list from simple data

Raw

rdf-list-from-data.md

This query generates an RDF list from an RDF graph that is a linear path. To set up initial data:

stardog query test "insert data { :a :p :b . :b :p :c . :c :p :d }"

The list generation query:

construct {
  ?start rdf:first ?s ;
         rdf:rest ?end .
  ?end rdf:first ?o .
  ?last rdf:rest rdf:nil .
}
where {
  { 
    ?s :p ?o
    bind(bnode(str(?s)) as ?start)
    bind(bnode(str(?o)) as ?end)
  }
  UNION {
    ?s :p ?o
    FILTER NOT EXISTS { ?o :p [] }
    BIND(bnode(str(?o)) as ?last)
  }
}

The result (note the pretty Turtle formatting to validate the well-formedness):

stardog query test -f PRETTY_TURTLE ~/cp/tmp/list.rq 
@prefix ...

( :a :b :c :d ) .

PS. The awkward bit is appending the rdf:nil terminator, probably can be done more efficiently...

jaw111 commented Oct 7, 2021

Just for the lolz, here's how you can do it as a SPARQL Update procedure:

prefix : <http://example.com/>

insert data {
  :a :p :b .
  :b :p :c .
  :c :p :d .
};

# add bnode pointer to distinct subjects and objects of predicate p
insert {
  [] rdf:first ?x .
}
where {
  select distinct ?x {
    { ?x :p [] }
    union
    { [] :p ?x }
  }
};

# replace predicate p by relations between bnode pointers
delete {
  ?s :p ?o .
}
insert {
  ?s_ rdf:rest ?o_ .
}
where {
  ?s :p ?o .
  ?s_ rdf:first ?s .
  ?o_ rdf:first ?o .
};

# add the nil terminator
insert {
  ?s rdf:rest rdf:nil .
}
where {
  ?s rdf:first [] .
  minus {
    ?s rdf:rest []
  }
};

The result of that should be ( :a :b :c :d ).

klinovp/rdf-list-from-data.md

Select an option

No results found

Select an option

No results found

jaw111 commented Oct 7, 2021

Uh oh!